当前位置：首页 → 问答吧 → 问个关于用ASP写入XML时的问题

问个关于用ASP写入XML时的问题

时间：2005-11-26

来源：互联网

guestbook.asp内容:

<%@Language="VBScript"%>
<%
'设置Web页面的信息
Response.Buffer = true
Response.Expires = -1

'显示留言函数init()
Function init()
entryForm()

'定义局部变量
Dim objXML
Dim arrNames
Dim arrEmails
Dim arrURLS
Dim arrMessages

'创建XMLDOM文档对象，用来存放留言
Set objXML = server.createObject("Msxml2.DOMDocument")
objXML.async = false
objXML.load(server.MapPath("guestbook.xml"))

'取得留言本各元素的集合
Set arrNames = objXML.getElementsByTagName("留言者姓名")
Set arrEmails = objXML.getElementsByTagName("电子邮件")
Set arrURLS = objXML.getElementsByTagName("网址")
Set arrMessages = objXML.getElementsByTagName("留言内容")

Response.Write "<table border='0' width='100%'>"
Response.Write "<tr><td bgcolor='#00CCFF' align='center' height='26'>"
Response.Write "<b>各位的留言如下：</b>"
Response.Write "</td></tr>"

'输出留言本各元素的内容，最新的留言先显示
For x=arrNames.length-1 To 0 Step -1
  Response.Write "<tr><td><a href=mailto:" & arrEmails.item(x).text & ">" & arrNames.item(x).text & "</a></td></tr>"
  Response.Write "<tr><td>网址：<a href=" & arrURLS.item(x).text & " target='_blank'>" & arrURLS.item(x).text & "</a><td></tr>"
  Response.Write "<tr><td>留言内容：</td></tr>"
  Response.Write "<tr><td bgcolor='#0099ff'>" & arrMessages.item(x).text &"</td></tr>"
  Response.Write "<tr><td> </td></tr>"
Next

Response.Write "</table>"
Set objXML = nothing
End Function

'向XML文件添加留言记录的函数addEntry()
Function addEntry()

'定义局部变量
Dim strName
Dim strEmail
Dim strURL
Dim strMessage

'取得留言表单的输入内容
strName = Request.Form("姓名")
strEmail = Request.Form("电子邮件")
strURL = Request.Form("网址")
strMessage = Request.Form("留言")

Dim objXML
Dim objEntry
Dim objName
Dim objEmail
Dim objURL
Dim objMessage

'向XML文件添加留言内容
Set objXML = server.createObject("Msxml2.DOMDocument")
objXML.async = false
objXML.load(server.MapPath("guestbook.xml"))

Set objEntry = objXML.createNode("element", "留言记录", "")
objXML.documentElement.appendChild(objEntry)

Set objName = objXML.createNode("element", "留言者姓名", "")
objEntry.appendChild(objName)
objName.text = strName

Set objEmail = objXML.createNode("element", "电子邮件", "")
objEntry.appendChild(objEmail)
objEmail.text = strEmail

Set objURL = objXML.createNode("element", "网址", "")
objEntry.appendChild(objURL)
objURL.text = strURL

Set objMessage = objXML.createNode("element", "留言内容", "")
objEntry.appendChild(objMessage)
objMessage.text = strMessage

objXML.save(server.MapPath("guestbook.xml"))

Response.Redirect("guestbook.asp")

End function

'填写和发送留言表单的函数entryForm()
Function entryForm()
  Response.Write "<p align='center'><b>XML 留言本例子</b></p>"
  Response.Write "<hr color='#000099' width='100%' noshade>"
  Response.Write "<form action=guestbook.asp?action=addEntry method=post>"
  Response.Write "<table border=1>"
  Response.Write "<tr><td>您的姓名：</td><td><input type=text name=姓名 /></td></tr>"
  Response.Write "<tr><td>电子邮件：</td><td><input type=text name=电子邮件 /></td></tr>"
  Response.Write "<tr><td>您的网址：</td><td><input type=text name=网址 /></td></tr>"
  Response.Write "<tr><td>您的留言：</td><td><textarea name=留言 cols=40 rows=5></textarea></td></tr>"
  Response.Write "<tr><td> </td><td><input type=submit value=发布留言 /></td></tr>"
  Response.Write "</table>"
  Response.Write "</form>"
End Function
%>
<html>
<head>
<title>XML 留言例子</title>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
</head>
<body>
<%
'判断是否发送了留言，并更新留言信息
Dim a
a = Request.Querystring("action")
If a<>"" Then
addEntry
else
init
End If
%>
</body>
</html>

guestbook.xml内容:

<?xml version="1.0" encoding="gb2312"?>
<留言本>
<留言记录>
<留言者姓名>孟宪会</留言者姓名>
<电子邮件>[email protected]</电子邮件>
<网址>http://go.163.com</网址>
<留言内容>测试成功</留言内容>
</留言记录>
<留言记录><留言者姓名>aaaaaa</留言者姓名><电子邮件>bbbbbb</电子邮件><网址>cccccccc</网址><留言内容>ddddddddd</留言内容></留言记录></留言本>

问题是除了第一条记录是正常格式之外,下面通过ASP添加的都是排成一行了,这个要怎么解决啊?可以的话帮忙修改下代码好吗,谢谢各位高手了

作者: wall 发布时间: 2005-11-26

我也想 , 不过写成一行更好, xml 本来就是用来存信息的嘛

作者: kancnspace 发布时间: 2005-12-27

好好看看这个！

常数    值描述
vbCr    Chr(13) 回车符。
vbCrLf    Chr(13) & Chr(10) 回车符与换行符。
vbFormFeed Chr(12) 换页符；在 Microsoft Windows 中不适用。
vbLf Chr(10) 换行符。
vbNewLine Chr(13) & Chr(10) 或 Chr(10) 平台指定的新行字符；适用于任何平台。
vbNullChar    Chr(0) 值为 0 的字符。
vbNullString 值为 0 的字符串与零长度字符串 ("") 不同；用于调用外部过程。
vbTab    Chr(9) 水平附签。
vbVerticalTab    Chr(11) 垂直附签；在 Microsoft Windows 中不适用。

作者: 7th 发布时间: 2005-12-28

问个关于用ASP写入XML时的问题

热门阅读

热门下载