按逗号截取字符并放入临时表问题

现有表 t1 有4列
id code source des
1 1,22,333 ccc ddd
2 4444.55555 eee fff

我要取数据为 @t （按照逗号截取并放入临时表）

code source des
1 ccc ddd 
22 ccc ddd 
333 ccc ddd 
4444 eee fff
55555 eee fff

请教高手如何实现？

自己写的。。。运行结果只有
code source des
4444 eee fff
55555 eee fff

declare @T table (code varchar(1000),source varchar(max),des varchar(max) )
declare @str varchar(max)
declare @source varchar(max)
declare @des varchar(max)
select @source = source from t1 
select @des = des from t1
select @str = code from t1 --where @i = id
while charindex(',',@str) > 0
begin
insert into @T values(substring(@str,1,charindex(',',@str)-1),@source,@des)
set @str = substring(@str,charindex(',',@str)+1,len(@str))
end
insert into @T values(@str,@source,@des)

select * from @T

SQL code

select code=substring(a.code,b.number,charindex(',',a.code+',',b.number+1)-b.number),
        [source],[des]
from t1 a,master..spt_values b
where b.type='p' and b.number<=len(a.code) and substring(a.code,b.number,1)<>',' 
and substring(','+a.code,b.number,1)=','

麻烦把帖子移到基础类版，帖子上方管理菜单可移动

如下面的例子

[code=sql]
create table #tb
(
strs varchar(50)
)

insert into #tb values ('500ml*1' ) 
insert into #tb values ('10g*10' )
insert into #tb values ('0.5DF:ASD*10' )
insert into #tb values ('10JSH*10*10')

select * from #tb

select SUBSTRING(strs,1,CHARINDEX('*',strs)-1) from #tb


--------------------------------------------------
500ml
10g
0.5DF:ASD
10JSH

(4 行受影响)

select LEFT(strs,CHARINDEX('*',strs)-1) from #tb


--------------------------------------------------
500ml
10g
0.5DF:ASD
10JSH

(4 行受影响)

方法三

select REPLACE(strs,right(strs,len(strs)-CHARINDEX('*',strs)+1),'') from #tb
----------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------
500ml
10g
0.5DF:ASD
10JSH

(4 行受影响)
方法四

create function getabovestar
(@gg nvarchar(20))
returns nvarchar(20)
as
begin
return (case when charindex('*',@gg)>0 then left(@gg,charindex('*',@gg)-1) else @gg end)
end
go
select dbo.getabovestar(gg) from #tb


[/code]

SQL code

--参考
拆分表:

--> --> (Roy)生成測試數據
 
if not object_id('Tab') is null
    drop table Tab
Go
Create table Tab([Col1] int,[COl2] nvarchar(5))
Insert Tab
select 1,N'a,b,c' union all
select 2,N'd,e' union all
select 3,N'f'
Go

--SQL2000用辅助表:
if object_id('Tempdb..#Num') is not null
    drop table #Num
go
select top 100 ID=Identity(int,1,1) into #Num from syscolumns a,syscolumns b
Select 
    a.Col1,COl2=substring(a.Col2,b.ID,charindex(',',a.Col2+',',b.ID)-b.ID) 
from 
    Tab a,#Num b
where
    charindex(',',','+a.Col2,b.ID)=b.ID --也可用 substring(','+a.COl2,b.ID,1)=','
--2000不使用辅助表
Select
    a.Col1,COl2=substring(a.Col2,b.number,charindex(',',a.Col2+',',b.number)-b.number) 
from 
    Tab a join master..spt_values  b 
    ON B.type='p' AND B.number BETWEEN 1 AND LEN(A.col2)
where
     substring(','+a.COl2,b.number,1)=','


SQL2005用Xml:

select 
    a.COl1,b.Col2
from 
    (select Col1,COl2=convert(xml,'<root><v>'+replace(COl2,',','</v><v>')+'</v></root>') from Tab)a
outer apply
    (select Col2=C.v.value('.','nvarchar(100)') from a.COl2.nodes('/root/v')C(v))b




SQL05用CTE:

;with roy as 
(select Col1,COl2=cast(left(Col2,charindex(',',Col2+',')-1) as nvarchar(100)),Split=cast(stuff(COl2+',',1,charindex(',',Col2+','),'') as nvarchar(100)) from Tab
union all
select Col1,COl2=cast(left(Split,charindex(',',Split)-1) as nvarchar(100)),Split= cast(stuff(Split,1,charindex(',',Split),'') as nvarchar(100)) from Roy where split>''
)
select COl1,COl2 from roy order by COl1 option (MAXRECURSION 0)

生成结果:
/*
Col1        COl2
----------- -----
1           a
1           b
1           c
2           d
2           e
3           f
*/

如果分隔符都是逗号:
SQL code

create table t1(id int,code varchar(20),source varchar(10),[des] varchar(10))
insert into t1 select 1,'1,22,333','ccc','ddd'
insert into t1 select 2,'4444,55555','eee','fff'
go
select substring(a.code,b.number,charindex(',',a.code+',',b.number+1)-b.number)code,source,des
from t1 a,master..spt_values b
where b.type='p' and b.number<=len(a.code) and substring(a.code,b.number,1)<>',' and substring(','+a.code,b.number,1)=','
/*
code                 source     des
-------------------- ---------- ----------
1                    ccc        ddd
22                   ccc        ddd
333                  ccc        ddd
4444                 eee        fff
55555                eee        fff

(5 行受影响)

*/
go
drop table t1

否则,先用逗号拆分存入临时表,再用小数点拆分.

SQL code

if object_id('t1') is not null
   drop table t1
go
create table t1
(
 id int,
 code varchar(20),
 source varchar(10),
 des varchar(10)
)
go
insert into t1
select 1,'1,22,333','ccc','ddd' union all
select 2,'4444,55555','eee','fff'
go
select code=substring(code,number,charindex(',',code+',',number)-number),source,des from t1 a cross join master..spt_values b where type='p' and number between 1 and len(code) and substring(','+code,number,1)=','
go
/*
code                 source     des
-------------------- ---------- ----------
1                    ccc        ddd
22                   ccc        ddd
333                  ccc        ddd
4444                 eee        fff
55555                eee        fff

(5 行受影响)

*/

很受用，但是我这个是好几万条数据master..spt_values 能支持吗？

只要你字段里最大逗号数不超过2048，就可以

我是说code里一行数据里逗号数不超过2048

OK 谢谢了 我试试。。