求解决方法，急

第一次发帖求教，希望得到帮助
现在有三张表，表A、表B、表C，表C是关联表，将表A和表B以多对多的关系关联起来，机构如下

表A 表B  
aId aText bID bText
------------ -------------
1 A 1 广州
2 B 2 深圳
3 C 3 东莞

表C
aId bId
------------
1 1
1 2
2 1
2 2
2 3
3 3

现在问，如何写一个存储过程得到以下的表Temp

表Temp
aId aText aCity
----------------------------
1 A 广州、深圳
2 B 广州、深圳、东莞
3 C 东莞


诚心请教，不尽感谢

SQL code

/*
标题：按某字段合并字符串之一(简单合并)
作者：爱新觉罗.毓华(十八年风雨,守得冰山雪莲花开)
时间：2008-11-06
地点：广东深圳

描述：将如下形式的数据按id字段合并value字段。
id    value
----- ------
1     aa
1     bb
2     aaa
2     bbb
2     ccc
需要得到结果：
id     value
------ -----------
1      aa,bb
2      aaa,bbb,ccc
即：group by id, 求 value 的和（字符串相加）
*/
--1、sql2000中只能用自定义的函数解决
create table tb(id int, value varchar(10))
insert into tb values(1, 'aa')
insert into tb values(1, 'bb')
insert into tb values(2, 'aaa')
insert into tb values(2, 'bbb')
insert into tb values(2, 'ccc')
go

create function dbo.f_str(@id varchar(10)) returns varchar(1000)
as
begin
  declare @str varchar(1000)
  select @str = isnull(@str + ',' , '') + cast(value as varchar) from tb where id = @id
  return @str
end
go

--调用函数
select id , value = dbo.f_str(id) from tb group by id

drop function dbo.f_str
drop table tb


--2、sql2005中的方法
create table tb(id int, value varchar(10))
insert into tb values(1, 'aa')
insert into tb values(1, 'bb')
insert into tb values(2, 'aaa')
insert into tb values(2, 'bbb')
insert into tb values(2, 'ccc')
go

select id, [value] = stuff((select ',' + [value] from tb t where id = tb.id for xml path('')) , 1 , 1 , '')
from tb
group by id

drop table tb


--3、使用游标合并数据
create table tb(id int, value varchar(10))
insert into tb values(1, 'aa')
insert into tb values(1, 'bb')
insert into tb values(2, 'aaa')
insert into tb values(2, 'bbb')
insert into tb values(2, 'ccc')
go
declare @t table(id int,value varchar(100))--定义结果集表变量
--定义游标并进行合并处理
declare my_cursor cursor local for
select id , value from tb
declare @id_old int , @id int , @value varchar(10) , @s varchar(100)
open my_cursor
fetch my_cursor into @id , @value
select @id_old = @id , @s=''
while @@FETCH_STATUS = 0
begin
    if @id = @id_old
       select @s = @s + ',' + cast(@value as varchar)
    else
      begin
        insert @t values(@id_old , stuff(@s,1,1,''))
        select @s = ',' + cast(@value as varchar) , @id_old = @id
      end
    fetch my_cursor into @id , @value
END
insert @t values(@id_old , stuff(@s,1,1,''))
close my_cursor
deallocate my_cursor

select * from @t
drop table tb

SQL code

--> --> (Roy)生成測試數據
 
if not object_id('Tempdb..#A') is null
    drop table #A
Go
Create table #A([aId] int,[aText] nvarchar(1))
Insert #A
select 1,N'A' union all
select 2,N'B' union all
select 3,N'C'
Go
--> --> (Roy)生成測試數據
 
if not object_id('Tempdb..#B') is null
    drop table #B
Go
Create table #B([bID] int,[bText] nvarchar(2))
Insert #B
select 1,N'广州' union all
select 2,N'深圳' union all
select 3,N'东莞'
Go

--> --> (Roy)生成測試數據
 
if not object_id('Tempdb..#C') is null
    drop table #C
Go
Create table #C([aId] int,[bId] int)
Insert #C
select 1,1 union all
select 1,2 union all
select 2,1 union all
select 2,2 union all
select 2,3 union all
select 3,3
Go
Select 
*,
[aCity]=stuff((select '、'+[bText] from #B as b inner join #C as c on c.[bId]=b.[bID] and c.[aId]=a.[aId] for xml path('')),1,1,'') 
from #A as a

/*
aId    aText    aCity
1    A    广州、深圳
2    B    广州、深圳、东莞
3    C    东莞
*/

SQL code

或用


select 
    a.*,[aCity]=stuff(b.[aCity].value('/R[1]','nvarchar(max)'),1,1,'')
from 
    #A a
Cross apply
    (select [aCity]=(select '、'+[bText] from #B as b inner join #C as c on c.[bId]=b.[bID] and c.[aId]=a.[aId] for xml path(''), ROOT('R'), TYPE))b


/*
aId    aText    aCity
1    A    广州、深圳
2    B    广州、深圳、东莞
3    C    东莞
*/